' -------------------------------------------------------------------------
' Program Description
' -------------------------------------------------------------------------
'
' Demonstrates GOSUB with parameter passing across page boundaries. Note
' that the GOSUB keyword is no longer required when using version 1.2
' syntax (SUB definition).  Note, too, that the INVERT subroutine behaves
' like a function by returning a value.


' -------------------------------------------------------------------------
' Device Settings
' -------------------------------------------------------------------------

DEVICE          SX28, OSC4MHZ, TURBO, STACKX, OPTIONX
FREQ            4_000_000


' -------------------------------------------------------------------------
' IO Pins
' -------------------------------------------------------------------------

LEDs            VAR     RB
TRIS_LEDs       VAR     TRIS_B


' -------------------------------------------------------------------------
' Constants
' -------------------------------------------------------------------------

Speed           CON     150                     ' loop delay control


' -------------------------------------------------------------------------
' Variables
' -------------------------------------------------------------------------

zigzag          VAR     Byte                    ' zigzag controller

temp1           VAR     Byte                    ' work vars
temp2           VAR     Byte


' =========================================================================
  PROGRAM Start
' =========================================================================


' -------------------------------------------------------------------------
' Subroutine Declarations
' -------------------------------------------------------------------------

DELAY           SUB     1, 2                    ' base { x multiplier }
INVERT          SUB     1                       ' register address


' -------------------------------------------------------------------------
' Program Code
' -------------------------------------------------------------------------

Start:
  TRIS_LEDs = %00000000                         ' make LEDs pins outputs
  zigzag = %00000001

Main:
  DO
    LEDs = INVERT zigzag                        ' invert LED pattern
    DELAY Speed                                 ' loop delay
    zigzag = zigzag << 1                        ' shift bit left
  LOOP UNTIL zigzag = %10000000

  DO
    LEDs = INVERT zigzag
    DELAY Speed
    zigzag = zigzag >> 1                        ' shift bit right
  LOOP UNTIL zigzag = %00000001
 
  GOTO Main


' -------------------------------------------------------------------------
' Subroutines Code
' -------------------------------------------------------------------------

' Use: DELAY base {, multiplier }
' -- pauses 'base' * (optional) 'multiplier' milliseconds

DELAY:
  temp1 = __PARAM1                              ' capture parameters
  IF __PARAMCNT = 1 THEN                        ' if no multiplier
    temp2 = 1                                   ' - set to 1
  ELSE
    temp2 = __PARAM2
  ENDIF
  IF temp1 > 0 THEN
    IF temp2 > 0 THEN 
      PAUSE temp1 * temp2                       ' do the pause
    ENDIF
  ENDIF
  RETURN


' Use: aVar = INVERT theByte
' -- inverts the bits in 'theByte'

INVERT:
  temp1 = __PARAM1                              ' get current value
  temp1 = ~temp1                                ' invert the bits
  RETURN temp1                                  ' return value to caller

  .